apoc.neighbors.tohop.count

Details
Syntax	`apoc.neighbors.tohop.count(node [, relTypes, distance ]) :: (value)`
Description	Returns the count of all `NODE` values connected by the given `RELATIONSHIP` values in the pattern within the specified distance.
Input arguments	Name	Type	Description
	`node`	`NODE`	The starting node for the algorithm.
	`relTypes`	`STRING`	A list of relationship types to follow. Relationship types are represented using APOC’s rel-direction-pattern syntax; `[<]RELATIONSHIP_TYPE1[>]\|[<]RELATIONSHIP_TYPE2[>]\|…`. The default is: ``.
	`distance`	`INTEGER`	The max number of hops to take. The default is: `1`.
Return arguments	Name	Type	Description
Return arguments	`value`	`INTEGER`	The total count of neighboring nodes within the given hop distance.

Usage Examples

The examples in this section are based on the following sample graph:

MERGE (mark:Person {name: "Mark"})
MERGE (praveena:Person {name: "Praveena"})
MERGE (joe:Person {name: "Joe"})
MERGE (lju:Person {name: "Lju"})
MERGE (michael:Person {name: "Michael"})
MERGE (emil:Person {name: "Emil"})
MERGE (ryan:Person {name: "Ryan"})

MERGE (ryan)-[:FOLLOWS]->(joe)
MERGE (joe)-[:FOLLOWS]->(mark)
MERGE (mark)-[:FOLLOWS]->(emil)
MERGE (michael)-[:KNOWS]-(emil)
MERGE (michael)-[:KNOWS]-(lju)
MERGE (michael)-[:KNOWS]-(praveena)
MERGE (emil)-[:FOLLOWS]->(joe)
MERGE (praveena)-[:FOLLOWS]->(joe)

This procedure computes a node’s neighborhood up to a specified hop count.

The following returns the number of people that Praveena FOLLOWS up to 2 hops:

MATCH (p:Person {name: "Praveena"})
CALL apoc.neighbors.tohop.count(p, "FOLLOWS>", 2)
YIELD value
RETURN value

Results
value
2

If we also want to know which nodes are in our neighborhood, we can do that as well. See apoc.neighbors.tohop.

More documentation of apoc.neighbors.tohop.count