apoc.neighbors.byhop.count

Details
Syntax	`apoc.neighbors.byhop.count(node [, relTypes, distance ]) :: (value)`
Description	Returns the count of all `NODE` values connected by the given `RELATIONSHIP` types within the specified distance.
Input arguments	Name	Type	Description
	`node`	`NODE`	The starting node for the algorithm.
	`relTypes`	`STRING`	A list of relationship types to follow. Relationship types are represented using APOC’s rel-direction-pattern syntax; `[<]RELATIONSHIP_TYPE1[>]\|[<]RELATIONSHIP_TYPE2[>]\|…`. The default is: ``.
	`distance`	`INTEGER`	The max number of hops to take. The default is: `1`.
Return arguments	Name	Type	Description
Return arguments	`value`	`LIST<ANY>`	A list of neighbor counts for each distinct hop distance.

Usage Examples

The examples in this section are based on the following sample graph:

MERGE (mark:Person {name: "Mark"})
MERGE (praveena:Person {name: "Praveena"})
MERGE (joe:Person {name: "Joe"})
MERGE (lju:Person {name: "Lju"})
MERGE (michael:Person {name: "Michael"})
MERGE (emil:Person {name: "Emil"})
MERGE (ryan:Person {name: "Ryan"})

MERGE (ryan)-[:FOLLOWS]->(joe)
MERGE (joe)-[:FOLLOWS]->(mark)
MERGE (mark)-[:FOLLOWS]->(emil)
MERGE (michael)-[:KNOWS]-(emil)
MERGE (michael)-[:KNOWS]-(lju)
MERGE (michael)-[:KNOWS]-(praveena)
MERGE (emil)-[:FOLLOWS]->(joe)
MERGE (praveena)-[:FOLLOWS]->(joe)

This procedure computes a node’s neighborhood at multiple hop counts.

The following returns the number of people that Emil KNOWS and the number that have FOLLOWS relationships to him, at up to 3 hops:

MATCH (p:Person {name: "Emil"})
CALL apoc.neighbors.byhop.count(p, "KNOWS|<FOLLOWS", 3)
YIELD value
RETURN value

Results
value
[2, 3, 1]

And as expected we have a count of 2 at level 1, 3 at level 2, and 1 at level 3.

We could even turn that list of numbers into a map with the key being the number of hops and the value the neighborhood size. The following query shows how to do this using the apoc.map.fromLists function:

MATCH (p:Person {name: "Emil"})
CALL apoc.neighbors.byhop.count(p, "KNOWS|<FOLLOWS", 3)
YIELD value
RETURN apoc.map.fromLists(
         [value in range(1, size(value)) | toString(value)],
         value) AS value

Results
value
{`1`: 2, `2`: 3, `3`: 1}

If we also want to know which nodes are in our neighborhood, we can do that as well. See apoc.neighbors.byhop.

More documentation of apoc.neighbors.byhop.count